**Practical 8**

1. First, bring together all the things we have learned about DCGs for English into one DCG. In particular, today we say how to use extra arguments to deal with the subject/object distinction, and in the exercises you were asked to use additional arguments to deal with the singular/plural distinction. Write a DCG which handles both. Moreover, write the DCG in such a way that it will produce parse trees, and makes use of a separate lexicon.

s(s(NP,VP)) --> np(NP,X,subject), vp(VP,X).

np(np(DET,N),X,\_) --> det(DET,X), n(N,X).

np(np(PRO),X,Y) --> pro(PRO,X,Y).

vp(vp(V,NP),X) --> v(V,X), np(NP,\_,object).

vp(vp(V),X) --> v(V,X).

det(det(DET),X) --> [DET], {lex(DET,det,X)}.

n(n(N),X) --> [N], {lex(N,n,X)}.

pro(pro(PRO),X,Y) --> [PRO], {lex(PRO,pro,X,Y)}.

v(v(V),X) --> [V], {lex(V,v,X)}.

lex(he,pro,singular,subject).

lex(she,pro,singular,subject).

lex(they,pro,plural,subject).

lex(him,pro,singular,object).

lex(her,pro,singular,object).

lex(them,pro,plural,object).

lex(the,det,\_).

lex(a,det,singular).

lex(man,n,singular).

lex(woman,n,singular).

lex(men,n,plural).

lex(women,n,plural).

lex(shoots,v,singular).

lex(shoot,v,plural).

1. Once you have done this, extend the DCG so that noun phrases can be modified by adjectives and simple prepositional phrases (that is, it should be able to handle noun phrases such as “the small frightened woman on the table” or “the big fat cow under the shower”). Then, further extend it so that the distinction between first, second, and third person pronouns is correctly handled (both in subject and object form).

s(s(NP,VP)) --> np(NP,X,Y,subject), vp(VP,X,Y).

np(np(DET,NBAR,PP),X,Y,\_) --> det(DET,X), nbar(NBAR,X,Y), pp(PP).

np(np(DET,NBAR),X,Y,\_) --> det(DET,X), nbar(NBAR,X,Y).

np(np(PRO),X,Y,Z) --> pro(PRO,X,Y,Z).

vp(vp(V),X,Y) --> v(V,X,Y).

vp(vp(V,NP),X,Y) --> v(V,X,Y), np(NP,\_,\_,object).

nbar(nbar(JP),X,3) --> jp(JP,X).

pp(pp(PREP,NP)) --> prep(PREP), np(NP,\_,\_,object).

jp(N,X) --> n(N,X).

jp(jp(ADJ,JP),X) --> adj(ADJ), jp(JP,X).

det(det(DET),X) --> [DET], {lex(DET,det,X)}.

pro(pro(PRO),X,Y,Z) --> [PRO], {lex(PRO,pro,X,Y,Z)}.

v(v(V),X,Y) --> [V], {lex(V,v,X,Y)}.

prep(prep(PREP)) --> [PREP], {lex(PREP,prep)}.

n(n(N),X) --> [N], {lex(N,n,X)}.

adj(adj(ADJ)) --> [ADJ], {lex(ADJ,adj)}.

lex(i,pro,singular,1,subject).

lex(you,pro,singular,2,subject).

lex(he,pro,singular,3,subject).

lex(she,pro,singular,3,subject).

lex(it,pro,singular,3,subject).

lex(we,pro,plural,1,subject).

lex(you,pro,plural,2,subject).

lex(they,pro,plural,3,subject).

lex(me,pro,singular,1,object).

lex(you,pro,singular,2,object).

lex(him,pro,singular,3,object).

lex(her,pro,singular,3,object).

lex(it,pro,singular,3,object).

lex(us,pro,plural,1,object).

lex(you,pro,plural,2,object).

lex(them,pro,plural,3,object).

lex(shoot,v,singular,1).

lex(shoot,v,singular,2).

lex(shoots,v,singular,3).

lex(shoot,v,plural,\_).

lex(the,det,\_).

lex(a,det,singular).

lex(man,n,singular).

lex(woman,n,singular).

lex(table,n,singular).

lex(cow,n,singular).

lex(shower,n,singular).

lex(on,prep).

lex(under,prep).

lex(men,n,plural).

lex(women,n,plural).

lex(small,adj).

lex(frightened,adj).

lex(big,adj).

lex(fat,adj).